Zum
Ja gibt es auch in diesem Fall das berühmte
aber. Es hängt davon ab, was man machen möchte und welchen Webserver auf welcher Plattform (Win9x, NT Workstation, NT Server) man einsetzt. Grundsätzlich gilt folgendes: nur unter IIS/NT Server kann man mit Bordmitteln Emails versenden - und zwar dann, wenn man den SMTP Service mitinstalliert hat.
Eine universelle Methode, Emails zu versenden, ist die Verwendung von Emailkomponenten von Drittherstellern. Eine sehr beliebte - AspMail - haben wir ausführlich in einem
Artikel beschrieben. Diese ist sehr leistungsfähig und kann auf allen Plattformen eingesetzt werden.
Zurück zu den Bordmitteln: Wenn man IIS einsetzt und den SMTP Service installiert hat, kann man die Objekte der CDONTS (Collaboration Data Objects for NT Server) einsetzen. Das einfachste und gebräuchlichste ist das
NewMail Objekt. Wenn man das ganze mit einem kleinen Anfrageformular koppelt, könnte der Code wie folgt aussehen:
<% @LANGUAGE = VBScript %>
<% Option Explicit %>
<html>
<head>
<title>Anfrageformular</title>
</head>
<body bgcolor=#ffffff>
<%
Dim strName, strEmail, strQuery
strName = Trim(Request.Form("ClientName"))
strEmail = Trim(Request.Form("ClientEmail"))
strQuery = Trim(Request.Form("ClientQry"))
If (strName <> "" And strEmail <> "" And strQuery <> "") Then
Dim objMail, aRecipients
Set objMail = Server.CreateObject("CDONTS.NewMail")
objMail.From = "webmaster@asp24h.com"
objMail.To = strEmail
objMail.Subject = "Ihre Anfrage, " & strName
aRecipients = Array("christophw@alphasierrapapa.com", _
"webmaster@alphasierrapapa.com")
objMail.BCC = Join(aRecipients, ";")
objMail.Body = strQuery
objMail.Send
Response.Write "Vielen Dank für Ihre Anfrage!"
Set objMail = Nothing
Else
%>
<h1>Geben Sie Ihre Anfrage ein</h1>
<FORM ACTION="<%=Request.ServerVariables("SCRIPT_NAME")%>" METHOD=POST>
<TABLE BORDER=0>
<tr>
<td>Name</td>
<td><INPUT TYPE=TEXT NAME="ClientName" VALUE="" SIZE=40></td>
</tr>
<tr>
<td>EMailadresse</td>
<td><INPUT TYPE=TEXT NAME="ClientEmail" VALUE="" SIZE=40></td>
</tr>
<tr>
<td valign=top>Kommentar/Frage</td>
<td><TEXTAREA NAME="ClientQry" COLS=40 ROWS=10></TEXTAREA></td>
</tr>
<tr><td></td><td><INPUT TYPE=SUBMIT VALUE="Abschicken"></td></tr>
</TABLE>
</FORM>
<% End If %>
</body>
</html>